Хороший чат ждет в свои объятья еще 50 участников. Войти в дом 🐱

Читать полностью…

А вот ещё один классный способ интеграции Таблиц Гугл и телеграм

Читать полностью…

Новая Таблица чата на Октябрь 2024 уже в работе https://docs.google.com/spreadsheets/d/1OEwu8AcVl8YdFnDisez-u6TRWVQPsA9wFce1U5ywTwU/edit?usp=sharing

Что означает заголовок ТЧ? Разберем

Полный заголовок
Таблица чата t.me/google_sheets_pro #27 [10/2024]

Адрес для скриншотов вместо водяного знака
Таблица чата t.me/google_sheets_pro

Порядковый номер
#27

Месяц, в который действует ТЧ
[10/2024]

Продуктивного дня 👨🏼‍💻✅

_________________
PS: Изучаете Таблицы? Море примеров с 2021 года в Таблицах чата тут https://drive.google.com/drive/folders/1mgzpM6dID_GUnzo-aQAAEv3kpFEmtgPx?usp=drive_link

Читать полностью…

О работе финансовым директором глазами Софьи: что на самом деле нужно уметь, чтобы стать финансовым директором? Так ли сложно вникнуть в управленческий учет и автоматизировать этот процесс?

Софья автор канала Мастер CFO, знает ответ на этот вопрос. А ещё она бесплатно выкладывает автоматизированные таблицы Google, Ecxel, которые упростят жизнь любому, раскрывает секреты работы в 1С и разбирает случаи из практики.

Рекомендуем к прочтению и сохранению:

→ 8 телеграмм-каналов по поиску работы для финансиста.

→ Авторская методичка по анализу трех ключевых управленческих отчётов: ОДДС, ОПиУ и Баланс.
(Старая цена: 10 000 руб Новая цена: 0 руб.)

→ 10 лайфхаков работы в 1С, которые упростят жизнь любому бухгалтеру и позволят сэкономить сотни часов рабочего времени

→ 20 таблиц для начинающего финансиста для входа в управленческий учет.

→ Инструкция по автоматизации финансового учета.

И немного профессионального юмора ⬇️

«Как вы с такой точностью выполняете планы? А мы просто неправильно считаем 😀»

Присоединяйтесь, у нас интересно ✅ @findir_pro

Читать полностью…

Множественные зависимые выпадающие списки

Всем привет! Алексей @Sag1ttar1us продолжает объяснять про связанные списки. Внимательно читаем и говорим спасибо автору! 👇


Мы уже умеем делать одиночные зависимые выпадающие списки.
Теперь мы научимся делать множественные.

1. Исходные данные всё те же - лист Data.
2. Наш рабочий лист - лист Main.
3. Служебный листы, где будут технические данные:
3.1. по областям, соответствующим выбранным странам.
3.2. по городам, соответствующим выбранным областям.

Формулы на служебных листах будут почти такими же, но так как выбранных значений у нас много, используем MAP.
Для областей:

=LET(  ...
  MAP(input_country; LAMBDA(_input_country;
    TRANSPOSE(UNIQUE(
      FILTER(data_region;
        data_country = _input_country ))))))

Для городов:

=LET( ...
  MAP(input_country; input_region;
    LAMBDA(_input_country; _input_region;
      TRANSPOSE(UNIQUE(
        FILTER(data_city;
          data_country = _input_country;
          data_region  = _input_region ))))))

⚠️И теперь важный момент по созданию собственно самих выпадающих списков. По умолчанию ссылка на диапазон становится абсолютной. А так как у нас много строк, нам нужно чтоб ссылка оставалось относительной (без $).


Присоединяйтесь к сообществу профессионалов Google Таблиц, делитесь знаниями и помогайте друг другу!
💬 Чат
📢 Канал

#решения #выпадающие_списки #связанные_списки #зависимые_списки

Читать полностью…

#новость

Новые обновления таблиц в Таблицах:

1. Теперь можно создать пустую таблицу. И как это на старте не догадались?🙈🤦

2. Можно ссылаться на таблицы через IMPORTRANGE. Например, если у вас есть таблица с именем "Таблица1" и заголовками "Столбец 1", "Столбец 2", "Столбец 3" и т. д.:

- Чтобы импортировать диапазон таблицы, включая заголовки: =IMPORTRANGE(spreadsheet_url; "Таблица1[#ALL]")
- Чтобы импортировать только нижние колонтитулы итого таблицы: =IMPORTRANGE(spreadsheet_url; "Таблица1[#TOTALS]")
- Чтобы импортировать диапазон таблицы, исключая заголовки: =IMPORTRANGE(spreadsheet_url; "Таблица1[#DATA]")
- Чтобы импортировать первые два столбца таблицы, включая заголовки: =IMPORTRANGE(spreadsheet_url; "Таблица1[[Column 1]:[Column 2];[#ALL]]")

3. Добавлены хоткеи для конвертирования диапазона в таблицы Таблиц

- Cmd+Opt+T для Mac
- Ctrl+Alt+T для Linux и Windows

Наш канал и чат про Таблицы и возможности 🚀

Читать полностью…

Связанные (зависимые) выпадающие списки формулами.

Всем привет! Один из самых активных и экспертных участников нашего сообщества делится знаниями о том, как сделать зависимые выпадающие списки.
Алексей @Sag1ttar1us, спасибо тебе за активность и помощь!
Слово предоставляется автору👇

🎰Выпадающий список в Google Таблицах — это удобный инструмент, который помогает эффективно управлять данными и улучшает взаимодействие с пользователями.
Зависимые выпадающие списки позволяет пользователю сначала выбрать из одного списка, а затем на основе этого выбора отображать связанные данные в другом списке.

📁В Google Таблицах данные в выпадающем списке нельзя задать непосредственно формулой, но можно получать из диапазона ячеек на листе. И уже в этом диапазоне можно задать формулу фильтрации данных на основе какого-либо критерия.

▶️В нашем примере при выборе страны, во втором списке автоматически подгружается список областей, и соответственно при выборе области в третьем списке - подгружается список городов.
0️⃣Первое, что необходимо - исходные данные в плоском виде:

Страна | Город | Область

1️⃣Первый выпадающий список - независимый, поэтому формируем его из диапазона/столбца исходных данных Страна.

2️⃣Далее, задаём формулу для столбца со служебными данными из списка областей выбранного города. Формула довольно простая, но чтоб было понятно, какие данные мы используем, я обозначу наши диапазоны с помощью переменных.

=LET(
 data_country; A2:A;
  data_region; B2:B;
input_country; F3;
IFNA(FILTER(data_region; data_country=input_country)))

Данные для 2-го выпадающего списка готовы. Создаём его из этого диапазона.

3️⃣Теперь нам нужен список городов в выбранной области выбранной страны. Формула аналогичная.

=LET(
 data_country; A2:A;
  data_region; B2:B;
    data_city; C2:C;
input_country; F3;
 input_region; F5;
IFNA(FILTER(data_city; data_country=input_country; data_region=input_region)))

Данные для 3-го выпадающего списка готовы. Создаём его из этого диапазона.

⚠️Есть один маленький недостаток таких зависимых выпадающих списков. Когда выбор сделан в 1-ом и 2-ом выпадающих списках, а затем снова изменён в 1-м списке, уже выбранное значение не меняется во 2-ом списке. Учитывайте это нюанс чтоб не возникало неожиданных ошибок. А в нашем примере с помощью условного форматирования мы делаем цвет текста серым для неактуальных данных.

PS. Естественно, Вы можете не использовать самокомментируемый код в формулах.

🟡PPS. А ещё у нас есть домашнее задание. Сделайте одной формулой все служебные столбцы для неограниченного числа "категорий". Например,
СТРАНА | Область | Город | Район | Улица и так далее.

🔗Пример в Таблице чата

Присоединяйтесь к сообществу профессионалов Google Таблиц, делитесь знаниями и помогайте друг другу!
💬 Чат
📢 Канал

Читать полностью…

👀 Функция FILTER: Мощный инструмент для анализа данных в Google Таблицах

Привет, умные пользователи Google Таблиц! Сегодня мы разберем функцию #FILTER - незаменимый помощник для тех, кто работает с большими объемами данных. Давайте посмотрим, как эта функция может сделать вашу работу эффективнее.

🔍 Что делает FILTER?

FILTER позволяет извлекать строки (и даже столбцы) из диапазона данных, которые соответствуют заданным условиям. Это похоже на использование сита: вы просеиваете большой объем информации и оставляете только то, что вам нужно.

📝 Синтаксис:

=FILTER(
  диапазон;
  условие1;
  [условие2; ...]
)

🛠 Примеры использования:

Фильтрация по одному условию:
Допустим, у нас есть таблица продаж с колонками "Товар" (A), "Количество" (B) и "Цена" (C), на скриншоте она слева.

Чтобы выбрать все товары с ценой выше 1000:

=FILTER(
  A2:C100; 
  C2:C100 > 1000
)

Фильтрация по нескольким условиям:

Теперь выберем товары с ценой выше 1000 И количеством больше 5:

=FILTER(
  A2:C100; 
  (C2:C100 > 1000) * (B2:B100 > 5)
)

☝️здесь логическое умножение: если хоть одно значение вернет ложь, то строка не пройдет проверку. Это тоже самое что умножить на ноль - любое значение станет нулём.

Использование ИЛИ логики:
Выберем товары с ценой выше 1000 ИЛИ количеством больше 10:

=FILTER(
  A2:C100; 
  (C2:C100 > 1000) + (B2:B100 > 10)
)

☝️а здесь логическое сложение: если хоть одно значение положительное, то в итоге будет "истина".

💡 Про-совет: Комбинируйте FILTER с другими функциями для еще более мощного анализа. Например, используйте SUMIF с результатами FILTER для подсчета итогов по отфильтрованным данным.

🚀 Где это может пригодиться:

👉 Анализ продаж: быстро находите топовые товары или проблемные позиции по данным из нашего сервиса
👉 Управление запасами: выявляйте товары с низким остатком (можно применить здесь)
👉 Работа с клиентской базой: фильтруйте клиентов по различным параметрам
👉 Финансовый анализ: выделяйте транзакции, соответствующие определенным критериям (например, я так нахожу оплаченные счета на донат)

Раздел: #формулы
Функции: #FILTER

🔗Пример в Таблице чата

Превратите свои таблицы в инструмент принятия решений! Присоединяйтесь к сообществу профессионалов Google Таблиц:
💬 Чат
📢 Канал

Читать полностью…

⚠️🍂 Внимание! Разыскивается: Активность канала

Дорогие подписчики! С начала сентября наша активность в канале куда-то загуляла. Возможно, она:

🐻 Ушла в спячку раньше медведей 💤
🚗 Застряла в пробке по дороге из отпуска 🌴
📚 Сдает ЕГЭ по летним впечатлениям ☀️
☀️ Ловит вкусные и тёплые деньки бабьего лета 💃
🍁Учится фильтровать осенние листья функцией FILTER 📊

Если вы видели нашу активность или знаете, где она прячется, пожалуйста, сообщите ей, что мы скучаем и ждем её возвращения!

А пока мы её ищем, предлагаем вам поделиться в комментариях:

1️⃣ Чего вам не хватает в канале?
2️⃣ Какие темы вы хотели бы обсудить?
3️⃣ Может, у вас есть секретный способ вызова активности из осенней спячки? 🤔
🤫 А может, хотелось бы еще о чём-то, кроме этих Таблиц🤢?

Давайте вместе разбудим наш канал и сделаем эту осень продуктивной! 🚀📈

P.S. Обещаем, что скоро порадуем вас новыми постами и лайфхаками. Оставайтесь с нами!
#ОсеннееПробуждение #ГдеНашаАктивность #ГуглТаблицыНеСпят

Читать полностью…

#brand

Это Шитмеллоу (Sheetmallow) ☝️
Панятно!?

Читать полностью…

Семь способов суммировать продажи по датам в Google Таблицах

Wow!😳Ребята, вы просто молодцы! 👏
Недавно в нашем чате обсуждалась задача о суммировании продаж товара за определённый период, и вы выдали целых семь отличных решений. Это действительно впечатляет! Они у меня даже в скриншот не поместились! Спасибо, помогли!)

Особое спасибо @nn_28n за чёткое оформление вопроса в Таблице. Твой подход - пример для всех! Будем использовать твой пример как пример! 😀

🧐Давайте разберем каждое решение:

1. Использование FILTER:

=SUM(
  FILTER(
    C5:C;
    A5:A>=F4;
    A5:A<=F5;
    B5:B="товар 1"
  )
)

FILTER выбирает нужные данные, SUM суммирует их. Простое и эффективное решение.

2. Применение SUMIFS:

=SUMIFS(
  C:C;
  B:B;"Товар 1";
  A:A;">="&F4;
  A:A;"<="&F5
)

SUMIFS суммирует значения с несколькими условиями. Классический подход к такой задаче.

3. Решение с REDUCE и LAMBDA:

=REDUCE(
  ;
  C5:C;
  LAMBDA(
    acc;z;
    acc+IF(
      (OFFSET(z;;-2)>=F4)*
      (OFFSET(z;;-2)<=F5)*
      (OFFSET(z;;-1)="товар 1");
      z;
    )
  )
)

Продвинутое решение, использующее новые функции Google Таблиц.

4. Компактное решение с SUMPRODUCT:

=SUMPRODUCT(
  C5:C;
  (B5:B="товар 1")*
  (A5:A>=F4)*
  (A5:A<=F5)
)

SUMPRODUCT позволяет объединить умножение массивов и суммирование в одной формуле.

5. SUMPRODUCT с объединением условий:

=SUMPRODUCT(
  C5:C;
  (B5:B&A5:A>="Товар 1"&F4)*
  (B5:B&A5:A<="Товар 1"&F5)
)

Интересный подход с объединением строк для проверки условий.

6. Использование QUERY:

=CHOOSEROWS(
  QUERY(
    A4:C;
    "Select sum(Col3)
     where Col1 >= date '"&TEXT(F4;"YYYY-MM-DD")&"'
     and Col1 <= date '"&TEXT(F5;"YYYY-MM-DD")&"'
     and Col2 ='Товар 1'
     group by Col2";
    1
  );
  -1
)

QUERY позволяет использовать SQL-подобные запросы к данным в таблице.

7. Еще одно применение REDUCE:

=REDUCE(
  ;
  A5:A;
  LAMBDA(
    acc;z;
    acc+IF(
      (z>=F4)*
      (z<=F5)*
      (OFFSET(z;;1)="товар 1");
      OFFSET(z;;2);
    )
  )
)

Похоже на третье решение, но с итерацией по датам.

Каждое решение имеет свои преимущества и может быть оптимальным в зависимости от конкретной ситуации и размера данных.

Ваша креативность и знание функций Google Таблиц просто поражают. Каждое из этих решений по-своему интересно и может пригодиться в разных ситуациях. Спасибо всем, кто принял участие в обсуждении - вместе мы делаем наше сообщество сильнее и умнее! 🚀

Продолжайте делиться своими идеями и решениями. Кто знает, может именно ваш подход однажды станет ключом к решению сложной задачи!

Раздел: #формулы #решения

Функции: #SUM #FILTER #SUMIFS #REDUCE #LAMBDA #SUMPRODUCT #QUERY #CHOOSEROWS #OFFSET

🔗Пример в Таблице чата

Хотите больше продвинутых формул и приёмов? Присоединяйтесь к нашему сообществу экспертов:
💬 Чат
📢 Канал

Читать полностью…

#новость

Так, мультисписки появились. Визуально работают.

Начало тут /channel/GoogleSheets_ru/284

Интересно, как оно работает со скриптами, и что там в валидном значении? 🤔

ОБН: Только чипы можно сделать мультиселектами!

ОБН: Экранирование запятых /channel/google_sheets_pro/56665

Наш канал и чат про Таблицы и возможности 🚀

Читать полностью…

#изучение_с_0

Google Таблицы для начинающих. Функции и формулы

C14. Сложность формул

Формулы по сложности можно разделить на простые и сложные.

Простые формулы

Константы, ссылки на ячейки на той же странице и операторы — все это части простых формул. Как правило, задействована только одна функция или оператор, а вычисления выполняются в порядке слева направо:

=SUM(A3:C15)

=A1+B2+C3

Сложные формулы

Когда для вычисления требуется больше функций и операторов или порядок вычислений становится более сложным, формулы могут быстро усложниться. Эти сложные формулы часто включают ссылки на ячейки, несколько функций, констант, операторов и именованных диапазонов, что делает их длинными и запутанными. Расшифровка их может оказаться непростой задачей. Часто, если пользователи не прилагают усилия к улучшению читаемости формул, эта непростая задача может быть под силу только автору 😁

Некоторые рекомендации по работе со сложностью

✅ Старайтесь поддерживать читаемость формул
✅ Используйте одиночный пробел между операторами
✅ Многострочные формулы - лучше однострочных
✅ С помощью пробелов можно создавать визуальные отступы и декорировать вложенность

✅ Чтобы вставить разрыв строки для многострочной формулы используйте [ALT]+[ENTER]
✅ Для полного просмотра всей формулы разверните панель формул

Ниже, формула выглядит сложно - второй аргумент функции FILTER явно слишком длинный:

=FILTER(A2:E18;(B2:B18="Георгий")+(B2:B18="Юлиус")+(B2:B18="Зульфия"))

Сравните с:

=FILTER(
  A2:E18;
  (B2:B18="Георгий")+
    (B2:B18="Юлиус")+
      (B2:B18="Зульфия")
)

Многие способы улучшения приходят со временем, когда вы учитесь читать чужие формулы и стараетесь применять для себя или даже в команде, как рекомендации к чистоте кода.

⇐ Назад и Вперед ⇒

Наш канал и чат про Таблицы Гугл

Читать полностью…

#новость

Просмотр и структурирование данных Google Форм в виде таблицы в Таблицах

Что изменилось:
Теперь пользователям будет легче просматривать и структурировать данные из Форм в Таблицы благодаря новой функции.

Начиная с сегодняшнего дня, при создании нового листа на основе данных из Форм, Таблицы автоматически откроет эти данные в виде таблицы, придавая им формат и структуру. Если пользователь откроет уже существующий лист, связанный с Формой, изменения не будут применены автоматически. В этом случае пользователю нужно будет вручную преобразовать данные в таблицу, выбрав пункт меню Формат - Преобразовать в таблицу

Наш канал и чат про Таблицы, Формы и улучшения ⭐️

Читать полностью…

📊 Профи-приём: Находим общие элементы в двух списках

Привет! 👋 Сегодня разберём эффективный способ поиска совпадающих элементов в двух списках. Это пригодится для анализа данных, сверки остатков или оптимизации рабочих процессов. 💼

🎯 Задача:
Найти элементы, которые присутствуют в обоих списках.

🛒 Пример из жизни:
Вы хотите узнать, какие товары есть и в списке заказов (столбец A), и в списке на складе (столбец B).

🔑 Решение:
Используем мощное комбо функций FILTER и MATCH. Вот наша формула:

=FILTER(A2:A; MATCH(A2:A; B2:B; 0))

🧠 Как это работает:

1. MATCH(A2:A; B2:B; 0) ищет каждый элемент из диапазона A2:A в диапазоне B2:B. Если элемент найден, функция возвращает его позицию в B2:B. Если не найден - возвращает ошибку #Н/Д.

2. FILTER(A2:A; MATCH(A2:A; B2:B; 0)) использует результат MATCH как условие фильтрации. Она оставляет только те элементы из A2:A, для которых MATCH нашел соответствие (т.е. вернул число, а не ошибку).

Таким образом, формула выводит только те элементы из столбца A, которые также присутствуют в столбце B.

💡 Совет:
Чтобы найти элементы, которых нет в другом списке, можно изменить формулу:

=FILTER(A2:A; ISNA(MATCH(A2:A; B2:B; 0)))

Здесь ISNA проверяет, вернул ли MATCH ошибку #Н/Д. Это происходит, когда элемент не найден. Таким образом, формула выводит все элементы из A, которых нет в B.

Теперь вы можете быстро находить как общие, так и уникальные элементы в любых списках. Оптимизируйте свои рабочие процессы! 🚀

А как вы обычно решаете подобные задачи? Поделитесь в комментариях!

Раздел: #формулы
Функции: #FILTER #MATCH #ISNA

🔗 Пример в Таблице чата

Хотите больше полезных формул и приёмов? Присоединяйтесь к нашему сообществу:
💬 Чат
📢 Канал

#GoogleTables #АнализДанных #ЛайфхакиДляБизнеса #решения #сравнение_списков

Если этот материал тебе помог, можно отсыпать звёздочек. ☺️ Нам будет приятно.

👇⭐️

Читать полностью…

📊 Неожиданное открытие: Получаем список листов Гугл Таблицы без скриптов!

Привет, исследователи! 👋

Алексей, один из наших талантливых и пытливых участников сообщества сделал удивительное открытие. Оказывается, можно получить список всех листов таблицы с помощью формулы, без использования скриптов! Раньше мы считали это невозможным.

Давайте разберемся, как это работает.

Вот эта интересная формула:

=TRANSPOSE(
  SPLIT(
    INDEX(
      IMPORTHTML("ссылка на Таблицу"; "table"; 2)
    ; 2; 3)
  ; CHAR(10))
)

🔍Разберем её по частям:

1. #IMPORTHTML("ссылка на Таблицу"; "table"; 2)
Эта функция импортирует вторую таблицу с веб-страницы таблицы. В этой таблице содержится информация о листах.

2. #INDEX(...; 2; 3)
Извлекает значение из третьего столбца второй строки импортированной таблицы. Здесь как раз и находится список листов.

3. #SPLIT(...; CHAR(10))
Разделяет полученную строку на отдельные элементы. #CHAR(10) - это символ новой строки.

4. #TRANSPOSE(...)
Преобразует полученный горизонтальный список в вертикальный для удобства чтения.

⚠️ Важное ограничение: Эта формула работает только с таблицами, открытыми для просмотра по ссылке.

Почему? Потому что IMPORTHTML может импортировать данные только из общедоступных источников. Если таблица закрыта, функция не сможет получить доступ к её содержимому.

💡 Применение:
- Быстрый аудит структуры больших таблиц
- Автоматическое создание оглавлений
- Мониторинг изменений в структуре таблицы

Браво нашему сообществу за такое изобретательное решение! Это ещё раз доказывает, что совместными усилиями мы можем найти неожиданные подходы к решению задач.

А у вас есть интересные находки в работе с Google Таблицами? Поделитесь в комментариях!

Раздел: #формулы
Функции: #IMPORTHTML #INDEX #SPLIT #TRANSPOSE #CHAR

🔗Пример в Таблице чата

Присоединяйтесь к сообществу профессионалов Гугл Таблиц, делитесь знаниями и помогайте друг другу!
💬 Чат
📢 Канал

#лайфхаки #оглавление #решения #ТаблицыГугл #googlesheets

Читать полностью…

📊🏗 "Construction Sheets": Как приручить строительную документацию с помощью Гугл Таблиц

Привет, друзья! Сегодня у нас в гостях Михаил - разработчик, который создал нечто действительно крутое на базе Таблиц и Документов Гугл.

Готовы узнать, как можно превратить кошмар строительной документации в удобную и эффективную систему? Поехали!
Знакомьтесь - "Construction Sheets"!

🤔 Что это такое?
"Construction Sheets" - это набор инструментов для ведения типовой строительной документации на основе сервисов Google. По сути, это продвинутое "Слияние на Гуглах", которое позволяет легко и удобно работать с шаблонами документов.

🛠 Что умеет этот инструмент:

Собирает все в одном месте: Бесконечные формы актов и ведомостей, сертификаты, протоколы испытаний, исполнительные схемы и приказы - всё хранится в одном месте, прямо в Гугл Таблице.

Контроль удаленки: Теперь вы можете эффективно контролировать удаленных работников, которые ведут документацию в ваших таблицах.

Обучение новичков: Значительно упрощает процесс обучения новых сотрудников ведению исполнительной документации.

Стандартизация процессов: Помогает выработать понятные "процессы" ведения исполнительной документации в компании (а во многих компаниях этого до сих пор нет!).

Дисциплина на объектах: Помогает дисциплинировать ведение электронных журналов на объектах.

Доступность информации: Все примеры ведения исполнительной документации теперь в шаговой доступности для всех сотрудников ПТО компании.

🔧 Как это работает технически?

Михаил поделился некоторыми интересными решениями:

Ключевой "движок" программы построен на смарт-чипах, которые появились около года назад.
Активно используется multi-select для удобства работы.
Раньше использовалось инъецирование кода, но сейчас перешли на развёрнутые веб-приложения. Почему? У инъецирования были серьезные недостатки: мало триггеров на проект, трудно отслеживать ошибки кода при большом количестве таблиц.
Применяется PDFApp - библиотека для работы с PDF файлами. Работает медленно, но, как говорит Михаил, "прикольно".
Для удобства разработки используется Black Apps Script.

💡 Интересные наблюдения от Михаила:
"Большинство пользователей моего продукта - девушки! Многие думают, что у меня несерьезная разработка, но на самом деле она уже генерирует ощутимую экономию времени и человеческих ресурсов. Это своего рода секрет для непосвященных."

👨‍💻 Совет от Михаила для начинающих разработчиков:
"Google Apps Script и Google таблицы - это просто клондайк для непрофильных программистов. Здесь такой простор для разработки и делиться удобно! Превратите написание и поддержание своего проекта в экономический и градостроительный симулятор. Это позволяет не отлипать от проекта сутками."

🚀 Планы на будущее:
Михаил не собирается останавливаться на достигнутом. У него целая кипа заметок по необходимым нововведениям, исправлениям багов и упрощениям интерфейса. Из ближайших "киллер-фич" - интеграция "рукописных шрифтов". Код уже наполовину написан, осталось лишь взяться и доделать!

🎁 Хотите попробовать?
У Михаила есть демо-версия на целых 2 недели! Вот ссылки:
🔗Таблица
🤖Подписка


Присоединяйтесь к сообществу профессионалов Гугл Таблиц, делитесь знаниями и помогайте друг другу!
💬 Чат
📢 Канал

Раздел: #автоматизация #строительство #сервисы

Читать полностью…

Привет! Как вы заметили, у нас сегодня была опубликована реклама ☺️

Наше сообщество растёт, становится более ценным, и всё это благодаря вам! 🎆⭐️💪

Оставить незамеченным вклад админов было бы хамством, поэтому мы приняли решение поделить сегодняшнее вознаграждение между самыми активными участниками и таким образом выразить свою благодарность 🎁

Admin <@IT_sAdmin>
Игорь Дроздов <@Drozdov_Igor_Advisd>
Алексей 𝕆𝕕𝕪𝕤𝕤𝕖𝕦𝕤 <@Sag1ttar1us>
Vadim R <@rwr_vim>
Роман Игнатов <@romanigro>

Спасибо вам за ваш вклад и помощь! ❤️

Читать полностью…

Всем привет! Рассказал вот здесь как мы пытаемся развить свой сервис в Телеграм без единой Гугл Таблицы.

Спойлер: это неудобно, и мы сейчас думаем что прикрутить для хранения найденных контактов. Пока выбираем между Таблицами и NocoDB.

Что думаете, есть у нашего детища право на жизнь? А шансы на успех?

Читать полностью…

4 способа посчитать потоварные расходы на рекламу ВБ

Привет, друзья-аналитики! 👋 Сегодня разберем интересную задачу из нашего чата. Готовы прокачать свои навыки работы с формулами? Поехали! 🚀

🎯 Задача:
У нас есть два листа: "Воронка" и "Реклама". Нужно перенести данные о расходах на рекламу с листа "Реклама" на лист "Воронка", сопоставляя их по артикулу и дате. При этом на листе "Реклама" может быть несколько записей для одной комбинации артикула и даты.

Давайте разберем предложенные решения:

1️⃣ Формула с #XLOOKUP:

=ARRAYFORMULA(
  IF(A2:A="";
    ;
    XLOOKUP(
      A2:A&B2:B;
      'Реклама'!B2:B&'Реклама'!A2:A;
      'Реклама'!D2:D;
      "Не найдено"
    )
  )
)

Как это работает:
A2:A&B2:B - создает уникальный ключ из артикула и даты на листе "Воронка"
'Реклама'!B2:B&'Реклама'!A2:A - делает то же самое на листе "Реклама"
XLOOKUP ищет соответствие этих ключей и возвращает значение из столбца D листа "Реклама"

⚠️ Ограничение: Эта формула найдет только первое соответствие для каждой комбинации артикула и даты.

2️⃣ Формула с #VLOOKUP:

=ARRAYFORMULA(
  IFNA(
    VLOOKUP(
      B2:B&" "&A2:A; 
      {'Реклама'!A2:A&" "&'Реклама'!B2:B\ 'Реклама'!D2:D}; 
      2; 
      0
    );
  )
)

Как это работает:
B2:B&" "&A2:A - создает ключ поиска из даты и артикула
{'Реклама'!A2:A&" "&'Реклама'!B2:B\ 'Реклама'!D2:D} - создает временный массив для поиска
VLOOKUP ищет соответствие в этом массиве

⚠️ Ограничение: Как и предыдущая, эта формула найдет только первое соответствие.

3️⃣Продвинутая формула с #QUERY:

=ARRAYFORMULA(
  IFNA(
    VLOOKUP(
      B2:B&" "&A2:A; 
      QUERY(
        {'Реклама'!A2:A&" "&'Реклама'!B2:B\ 'Реклама'!D2:D}; 
        "Select Col1, SUM(Col2) group by Col1"
      ); 
      2; 
      0
    );
  )
)

Как это работает:
QUERY - суммирует все расходы для каждой уникальной комбинации даты и артикула
VLOOKUP - затем ищет соответствие в этом предобработанном массиве

👍 Преимущество: Эта формула корректно обрабатывает случаи с несколькими записями для одной комбинации артикула и даты.

4️⃣Элегантное решение с #MAP и #LAMBDA:

=ArrayFormula(
  MAP(
    A2:A;
    B2:B;
    LAMBDA(
      a;b; 
      SUMIF(
        'Реклама'!B2:B&'Реклама'!A2:A;
        a&b;
        'Реклама'!D2:D
      )
    )
  )
)

Как это работает:
MAP - применяет функцию к каждой паре значений из A2:A и B2:B
LAMBDA - создает временную функцию, которая использует SUMIF
SUMIF суммирует все соответствующие расходы для каждой комбинации артикула и даты

👍 Преимущество: Это решение и гибкое, и эффективное, корректно обрабатывающее множественные записи.

💡Итог: Третья и четвертая формулы наиболее универсальны, так как они суммируют все расходы для каждой комбинации артикула и даты.

А какое решение кажется вам наиболее элегантным? Поделитесь своим мнением в комментариях!

Раздел: #формулы #решения

Функции: #ARRAYFORMULA #XLOOKUP #VLOOKUP #QUERY #MAP #LAMBDA #SUMIF

🔗Пример в Таблице чата

Присоединяйтесь к сообществу профессионалов Google Таблиц, делитесь знаниями и помогайте друг другу!
💬 Чат
📢 Канал

#GoogleSheets #АнализДанных #Формулы #РаботаСДанными

Читать полностью…

🎰 Связанные выпадающие списки с мультивыбором — новое решение от нашего активного участника Игоря Дроздова. Спасибо тебе, Игорь, за твою помощь и вклад в сообщество! 👏

🖇 Что такое выпадающие списки с мультивыбором?

Выпадающие списки в Google Таблицах позволяют пользователям выбирать значения из заранее определённого списка, что упрощает ввод данных. Но что, если нам нужно выбрать несколько значений? Выпадающие списки с мультивыбором расширяют стандартный функционал, позволяя выбирать несколько элементов одновременно.

💡 Как это работает?

В Google Таблицах выпадающие списки можно создавать "из диапазона", где данные берутся из определенного диапазона ячеек на листе. Для того чтобы сделать зависимые списки, мы будем динамически изменять содержимое этих диапазонов на основе выбранных значений (например, страна и область). Результаты вычислений формул будут автоматически обновляться в этих диапазонах, что позволит отображать правильные значения в выпадающих списках.

Игорь поделился решением для создания связанных выпадающих списков с мультивыбором, которые динамически обновляются на основе предыдущих выборов. Это означает, что вы можете выбрать несколько значений в первом списке, и второй список обновится в соответствии с выбранными элементами.

📝 Пример решения

В качестве примера использования выбираем города, в зависимости от выбранных стран и их областей.
Вот формулы, которые позволяют это сделать:

1️⃣Формула для областей:

=UNIQUE(
  FILTER(
    B2:B;
    IF(
      E3="";
      A2:A<>"";
      MATCH(
        A2:A;
        SPLIT(E3;", ");
        0
      )
    )
  )
)

🤓 разбираем формулу:
- FILTER(B2:B; ...) — фильтрует диапазон столбца B, возвращая только те значения, которые соответствуют заданному критерию.
- IF(E3=""; A2:A<>""; ...) — если ячейка E3 пуста, фильтрует все строки, где столбец A не пустой. В противном случае сравнивает значения в столбце A с выбранными странами из ячейки E3.
- SPLIT(E3;", ") — разбивает строку в E3 на отдельные элементы, если в ней несколько стран, разделённых запятыми.
- MATCH(A2:A; SPLIT(E3;", ");0) — находит соответствия между значениями в столбце A и элементами списка стран.
- UNIQUE(...) — удаляет дублирующиеся значения из полученного списка.

2️⃣Формула для городов:

=UNIQUE(
  FILTER(
    C2:C;
    IF(
      E5="";
      MATCH(
        B2:B;
        G2:G;
        0
      );
      MATCH(
        B2:B;
        SPLIT(E5;", ");
        0
      )
    )
  )
)

🤓 разбираем формулу:
- FILTER(C2:C; ...) — фильтрует диапазон столбца C, возвращая города, которые соответствуют выбранной области.
- IF(E5=""; MATCH(B2:B; G2:G; 0); ...) — если ячейка E5 пуста, выбирает все города из столбца B, которые соответствуют выбранной области в столбце G. В противном случае сравнивает значения в столбце B с выбранными областями из ячейки E5.
- MATCH(B2:B; SPLIT(E5;", ");0) — находит соответствия между значениями в столбце B и выбранными областями, разделёнными запятыми.
- UNIQUE(...) — удаляет дублирующиеся города из списка.

⚠️ Важный нюанс: Обратите внимание, что при изменении выбора в одном из списков, предыдущие выборы могут не обновляться автоматически. Подобные задачи нужно решать уже с помощью Скриптов.

✍️ Так, и вот это еще законспектируйте:

Связанные списки правильно работают только со скриптом, всё остальное это костыли. Но иногда костыли - это именно то, что нужно!
Игорь©️

🔗Пример в Таблице чата

Присоединяйтесь к сообществу профессионалов Google Таблиц, делитесь знаниями и помогайте друг другу!
💬 Чат
📢 Канал

Читать полностью…

Ну что? Все уже скачали себе свой Гугл? Таблицы работают? Ногти целые? Корвалол не закончился? 😉

Читать полностью…

Новая Таблица чата на сентябрь https://docs.google.com/spreadsheets/d/102uGGTA6uZe6uzX-tq1KDKtu947KPNKj9zNs01zm25Q/edit?usp=sharing

Читать полностью…

#изучение_с_0

Google Таблицы для начинающих. Функции и формулы

C15. Использование функций для логических операций

Логические операции - основа расчетов. Они необходимы для проверки данных, сравнения результатов и принятия решений при расчетах.

Для реализации логических операций возможно использовать логические функции, такие как NOT(НЕ), AND(И), OR(ИЛИ) и другие. Их довольно легко интегрировать их с функцией IF(ЕСЛИ) и операторами сравнения.

Логические операторы играют решающую роль в принятии компьютером решений, позволяя выполнять даже самые простые задачи, такие как сортировка заказов по географическому региону. Без этих операторов этот процесс был бы затруднительным.

Функции NOT(НЕ), AND(И), OR(ИЛИ)

В логических операциях проверяются различные условия, и в зависимости от их выполнения или невыполнения запускаются определенные события. Существуют три основных логических оператора в Таблицах: оператор NOT(НЕ), оператор OR(ИЛИ) и оператор AND(И). Благодаря использованию этих функций можно эффективно оценить выполнение или невыполнение условий.

✅ Функция AND() проверяет несколько значений, чтобы определить, верны ли все. Если да, то результат истина; в противном случае это ложь.
✅ Функция NOT() меняет значение с истинного на ложное или наоборот.
✅ Функция OR() проверяет несколько значений, если хотя бы одно из них истина результат будет истинным. Если все аргументы ложь, то результат будет ложным.

Использование операторов сравнения совместно с логическими функциями

Самое практичное применение логических функций происходит совместно с операторами сравнения. Эти операторы служат для сравнения двух значений и определения соответствия определенному условию. Среди имеющихся в распоряжении операторов сравнения — оператор равенства, оператор "больше" и оператор "меньше".

В формулах при вычислениях операторы сравнения возвращают истинный или ложный результат. Эта функциональность делает их идеальным выбором для логических функций. Например, нужно сравнить два числа из разных ячеек, больше ли они 50, можно сделать это так:

=IF(A2>50,IF(B2>50,TRUE,FALSE),FALSE)

В качестве альтернативы можно использовать функции сравнения совместно с логическими функциями аналогичным образом:

=IF(AND(A2>50,B2>50),TRUE,FALSE)

Второй способ более читаем.

⇐ Назад и Вперед ⇒

Наш канал и чат про Таблицы Гугл

Читать полностью…

Добавили локализацию для расширения, о котором рассказывали ранее /channel/GoogleSheets_ru/312

https://github.com/vernak2539/chrome-extension-google-doc-default-zoom/pull/33

Ждем релиза.

Кстати, на удивление оказалось удобно. Правда, фильтра только для некоторых Таблиц не хватает. Нужно продумать эту фичу и добавить.

Наш канал и чат про Гугл Таблицы и расширения

Читать полностью…

☀️ Доброе утро!

Пока мы ломаем голову чего бы такого интересного-полезного рассказать вам вечером про решения задач в Таблицах, предлагаем небольшой перерыв от формул и функций!

Дмитрий решил поделиться историей создания Telegram-бота для автоматизации поиска клиентов. Спойлер: там есть про юзер-ботов, фильтрацию сообщений и планы по интеграции с ИИ! И Конечно же вспомнили нашу железную Катюху!

🔗 Читать статью

А теперь время для челленджа! 😉
1️⃣ Прочитайте статью
2️⃣ Оставьте лайк (👍 нам очень нужна ваша поддержка!)
3️⃣ Напишите комментарий (мы ценим каждое мнение!)
4️⃣ Поделитесь статьей с коллегами (вдруг им тоже нужен такой бот?)

Ваша активность - лучший стимул для нас создавать еще больше полезного контента!

Давайте поддержим наших разработчиков и покажем VC.ru, что комьюнити GoogleSheets.ru – самое крутое! 💪

П.С. Не забудьте подписаться на блог, чтобы не пропустить наши будущие публикации!

Дополнение: читать лучше НЕ из встроенного в Телеграм браузера

#GoogleSheets #TelegramBot #АвтоматизацияБизнеса #РазработкаБотов

Читать полностью…

🔍 Продвинутый поиск: Сравнение списков с частичным совпадением

Привет, профи работы с данными! 👋
Сегодня поднимаем планку и разбираем мощный инструмент для сравнения списков с частичным совпадением. Это незаменимый приём для тех, кто работает с большими объемами данных и нуждается в гибком поиске. 🔍

🎯 Задача:
Найти элементы, которые содержат совпадающие подстроки в другом списке.

🛍 Пример из жизни:
Представьте, что у вас есть список заказанных товаров (столбец A) и список товаров на складе (столбец B). Вы хотите найти все товары на складе, которые могут быть похожи на заказанные.

🔐 Решение:
Используем комбинацию функций ARRAYFORMULA, REGEXMATCH и TEXTJOIN. Вот наша супер-формула:

=ARRAYFORMULA(REGEXMATCH(A2:A; TEXTJOIN("|"; ИСТИНА; B2:B)))

🧠 Как это работает:
1. TEXTJOIN("|"; ИСТИНА; B2:B) объединяет все элементы из столбца B в одну строку, разделяя их символом "|". Это создаёт регулярное выражение для поиска.

2. REGEXMATCH(A2:A; ...) проверяет каждый элемент в столбце A на соответствие полученному регулярному выражению.

3. ARRAYFORMULA(...) применяет эту проверку ко всем ячейкам диапазона A2:A.

В результате вы получите массив логических значений (ИСТИНА/ЛОЖЬ), показывающих, содержит ли каждый элемент из A какую-либо подстроку из B.

💡 Совет:
Чтобы получить список элементов, а не логические значения, оберните формулу в FILTER:

=FILTER(A2:A; ARRAYFORMULA(REGEXMATCH(A2:A; TEXTJOIN("|"; ИСТИНА; B2:B))))

Это выведет только те элементы из A, которые содержат подстроки из B.

Теперь вы вооружены мощным инструментом для гибкого анализа данных. Используйте его с умом! 🚀

Как бы вы применили эту формулу в своей работе? Поделитесь идеями в комментариях!

Ответьте сами: Какую функцию и как нужно применить, чтобы найти совпадающие строки БЕЗ учета регистра?

Раздел: #формулы
Функции: #ARRAYFORMULA #REGEXMATCH #TEXTJOIN #FILTER

🔗 Пример в Таблице чата

Хотите больше продвинутых формул и приёмов? Присоединяйтесь к нашему сообществу экспертов:
💬 Чат
📢 Канал

#решения

upd. Отдельное спасибо активному участнику нашего сообщества @Sag1ttar1us за крутые варианты и примеры!

Читать полностью…

🚀 Как автоматизировать курьерскую службу с помощью Google? 🚀

Владельцы малого и среднего бизнеса!
Устали от неразберихи с заявками и отчетами водителей? Мы нашли решение!

В нашей новой статье мы расскажем, как с помощью бесплатных инструментов Google Forms и Google Sheets можно автоматизировать все ключевые процессы в курьерской службе. Снижение ошибок, экономия времени и удобство работы — всё это стало возможным без серьезных финансовых вложений.

🔧 Как создать динамическую систему управления заявками?
🛠 Как автоматизировать отчетность водителей?
📊 Как интегрировать данные с учетной системой?


Ответы на эти вопросы уже ждут вас в нашей статье! Вперед к оптимизации и росту вашей компании!

Наш подписчик Владислав (@theirishman00) наглядно и личным примером показывает как, не являясь профессиональным разработчиком, можно эффективно решать проблемы бизнеса.
Владислав, спасибо за интересный кейс!

🔗Читать статью📕

p.s. Если вам есть чем поделиться или похвастаться - Костя @GoogleSheets_ru_cm очень будет вам рад!

Хотите больше полезных кейсов? Присоединяйтесь к нашему сообществу:
💬 Чат
📢 Канал

#бизнес #логистика #автоматизация #GoogleForms #GoogleSheets #GoogleAppsScript #курьерскаяслужба

Читать полностью…

#расширения #приложения

Расширение браузера Chrome, котрое позволяет установить штатный зум(масштаб) Таблиц и Документов по умолчанию https://chromewebstore.google.com/detail/google-workspace-zoom-def/nflkcdlimipkgbacnfnhfecjgmojhklo?hl=ru

Наш канал и чат про Гугл Таблицы и расширения

Если эта информация помогла, можно отсыпать звёздочек. ☺️ Нам будет приятно.

👇⭐️

Читать полностью…

#изучение_с_0

Google Таблицы для начинающих. Функции и формулы

C13. Именованные диапазоны

Интересно, что можно назначать своебразные имена отдельным ячейкам и диапазонам. Это упрощает обработку наборов данных и позволяет быстрее перемещаться по формулам в Таблицах.

Самое полезно, что можно взять от таких имен - это ссылки на постоянные данные.

Представьте, что у вас есть общий коэффициен расчета для всей Таблицы. Вы можете назначить ячейке ярлык, другими словами - имя.
На минутку представим себя оператором звездолета. Подлетая к очередной планете, мы получаем от системы информацию о том, что ускорение свободного падения на ней составляет всего 100м/с2. Вы вводите этот параметр в настройки своей Таблицы, и теперь все расчеты по планете можно вести относительно этого параметра. Будем вводить в ячейку B4. В настройках именованных диапазонов укажем, что имя этой ячейки Ускорение_свободного_падения. Отлично, теперь, мы можем кое-что посчитать. Напрмиер, если в ячейке F11 указать массу тела, а в ячейке F12 высоту над поверхностью планеты, то можно узнать потенциальную энергию этого тела как =F11*F12*Ускорение_свободного_падения, а сила тяжести, действующая на тело будет =F11*Ускорение_свободного_падения. Вы можете теперь ссылаться на Ускорение_свободного_падения в любом месте своей Таблицы.

Обратите внимание, что невозможно создавать именованные диапазоны, используя несмежные ячейки.

Настрока именованных диапазонов

Чтобы определить именованный диапазон, выполните следующие действия:

✅ Выберите нужные соседние ячейки и убедитесь, что они выделены.
✅ Перейдите в меню Данные - Настроить именованные диапазоны. Это действие откроет панель с правой стороны.
✅ Присвойте имя диапазону и нажмите кнопку "Готово".

Благодаря этому вы сможете легко управлять любыми созданными вами диапазонами и изменять их.

Соглашение об именовании диапазонов

Формулы становятся более удобными, прозрачными и понятными, если вы используете именованные диапазоны. Однако соблюдение нескольких простых рекомендаций имеет решающее значение, когда дело доходит до присвоения имен этим диапазонам.

При выборе имени для диапазонов данных следует учитывать несколько требований надложенных Таблицами:

✅ Имя должно состоять только из символов подчеркивания, цифр или букв
✅ Другие знаки и пробелы не допускаются, т.е. имя диапазона не может быть, напрмиер, A3:Z12
✅ Оно не должно начинаться с цифры или слов TRUE, ИСТИНА, FALSE, ЛОЖЬ
✅ Длина имени должна быть от 1 до 250 символов

В случае ошибки, например использования пробелов в названии, вы получите уведомление о том, что такое имя сохранить нельзя. Важно использовать удобное соглашение об именовании, например, УскорениеСвободногоПадения или Ускорение_свободного_падения. Стоит отметить, что именованные диапазоны в Таблицах действуют аналогично абсолютным ссылкам на ячейки. Независимо от добавления или удаления строк и столбцов на листе Ускорение_свободного_падения остается неизменным. Вы можете свободно перемещать диапазон в разные места на листе, не влияя на результаты. Это очень удобно!

⇐ Назад и Вперед ⇒

Наш канал и чат про Таблицы Гугл

Читать полностью…